Seguidor de Linea

// Pines Sensores
const int SENSOR_IZQ = A0;
const int SENSOR_DER = A1;

// Pines Motores (igual que P5)
const int ENA = 5;
const int IN1 = 4;
const int IN2 = 7;
const int ENB = 6;
const int IN3 = 8;
const int IN4 = 12;

// Configuracion
const int UMBRAL = 500;      // Ajustar segun calibracion
const int VEL_BASE = 120;    // Velocidad normal
const int VEL_GIRO = 80;     // Velocidad en giros

void setup() {
  Serial.begin(9600);
  pinMode(ENA, OUTPUT);
  pinMode(IN1, OUTPUT);
  pinMode(IN2, OUTPUT);
  pinMode(ENB, OUTPUT);
  pinMode(IN3, OUTPUT);
  pinMode(IN4, OUTPUT);
  parar();
  delay(3000);  // Esperar 3 segundos antes de arrancar
}

void loop() {
  // Leer sensores
  int lecturaIzq = analogRead(SENSOR_IZQ);
  int lecturaDer = analogRead(SENSOR_DER);

  // Detectar linea (negro = lectura baja)
  bool lineaIzq = lecturaIzq < UMBRAL;
  bool lineaDer = lecturaDer < UMBRAL;

  // Decidir movimiento
  if (!lineaIzq && !lineaDer) {
    // Ambos ven blanco: linea en el centro
    avanzar(VEL_BASE);
  }
  else if (lineaIzq && !lineaDer) {
    // Izquierdo ve negro: girar izquierda
    girarIzquierda();
  }
  else if (!lineaIzq && lineaDer) {
    // Derecho ve negro: girar derecha
    girarDerecha();
  }
  else {
    // Ambos ven negro: cruce, avanzar lento
    avanzar(VEL_GIRO);
  }

  delay(10);
}

void avanzar(int velocidad) {
  digitalWrite(IN1, HIGH);
  digitalWrite(IN2, LOW);
  analogWrite(ENA, velocidad);
  digitalWrite(IN3, HIGH);
  digitalWrite(IN4, LOW);
  analogWrite(ENB, velocidad);
}

void girarIzquierda() {
  analogWrite(ENA, 0);           // Parar izquierdo
  analogWrite(ENB, VEL_GIRO);    // Derecho sigue
}

void girarDerecha() {
  analogWrite(ENA, VEL_GIRO);    // Izquierdo sigue
  analogWrite(ENB, 0);           // Parar derecho
}

void parar() {
  analogWrite(ENA, 0);
  analogWrite(ENB, 0);
}